[SAP ABAP] 엑셀 업로드 및 엑셀 데이터 가져오는 방법

SAP 시스템에서 엑셀 데이터를 읽고 변환하여 테이블에 저장하는 방법은 마이그레이션, 대량 데이터 입력, 인터페이스 연동 시 필수적인 기술입니다.

이번 글에서는 ABAP을 활용하여 엑셀 데이터를 가져오는 방법과 이를 SAP 테이블에 업로드하는 과정을 다뤄보겠습니다.

---

 

1. 엑셀 데이터 → SAP시스템

 

SAP에서는 대량 데이터를 수작업으로 입력하기 어려운 경우가 많습니다.

예를 들어, 구매 오더, 출고 데이터, 고객 정보 등을 엑셀에서 관리하다가 SAP로 일괄 업로드해야 하는 경우가 있습니다.

이때, ABAP을 활용하여 엑셀 데이터를 읽어와 인터널 테이블로 변환하여 보다 효율적인 데이터 처리가 가능합니다.

 

2. 엑셀 데이터 가져오기 및 업로드 이점

• 대량 데이터 처리: 수백~수천 개의 데이터를 한 번에 업로드할 수 있음
• 업무 효율성 향상: 수작업 입력을 줄여 시간과 비용 절감
• 데이터 정확성 증가: 사람이 직접 입력하는 경우보다 오류 발생 가능성이 낮음
• 자동화 가능: 배치 프로그램으로 스케줄링하여 정기적인 데이터 업로드 가능

 

3. 코드 설명

1) 파일 선택 팝업 열기

사용자가 업로드할 엑셀 파일을 선택할 수 있록 팝업을 실행합니다.

CALL FUNCTION 'F4_FILENAME'
  IMPORTING
    file_name = p_file.

 

2) 엑셀 데이터를 인터널 테이블로 변환

아래 함수를 사용하여 엑셀 데이터를 lt_excel_raw 인터널 테이블로 저장합니다.

CALL FUNCTION 'ALSM_EXCEL_TO_INTERNAL_TABLE'

 

3) 데이터 변환

각 컬럼을 SAP 테이블 필드에 매핑하여 변환된 데이터를 lt_excel 테이블에 저장합니다.

LOOP AT lt_excel_raw INTO ls_raw.
  CASE ls_raw-col.
    WHEN 1. ls_excel-mandt  = ls_raw-value.
    WHEN 2. ls_excel-userid = ls_raw-value.
    WHEN 3.
      ls_excel-passwd = ls_raw-value.
      APPEND ls_excel TO lt_excel.
      CLEAR: ls_excel.
  ENDCASE.
ENDLOOP.

 

4. 엑셀 업로드 및 데이터 가져오는 ABAP  전체 코드

엑셀 데이터를 가져오기 위해 SAP에서는 ALSM_EXCEL_TO_INTERNAL_TABLE 함수를 사용합니다.

이 함수는 엑셀 파일의 데이터를 INTERNAL TABLE로 변환해줍니다.

TABLES: alsmex_tabline, ztable.  " 엑셀 데이터를 저장할 인터널 테이블 및 CBO테이블 선언

DATA: lt_excel_raw TYPE TABLE OF alsmex_tabline,  " 엑셀 원본 데이터를 저장할 인터널테이블
      ls_raw       TYPE alsmex_tabline,           " 엑셀 원본 데이터의 개별 행을 저장하는 구조
      lt_excel     TYPE TABLE OF ztable,          " 변환된 데이터를 저장할 인터널테이블
      ls_excel     TYPE ztable,                   " 개별 행 데이터를 저장할 구조
      lv_file      TYPE rlgrap-filename,          " 업로드할 엑셀 파일의 경로를 저장할 변수
      lv_value     TYPE string.                   " 개별 셀 값을 저장할 변수

" 사용자가 파일을 선택하도록 하는 매개변수 선언
PARAMETERS: p_file TYPE rlgrap-filename OBLIGATORY.

" 파일 선택 팝업 (자동 파일 탐색기 실행)

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file.
  CALL FUNCTION 'F4_FILENAME'
    IMPORTING
      file_name = p_file.   " 파일 선택 후 경로를 p_file 변수에 저장


START-OF-SELECTION.

  " 선택한 파일 경로를 화면에 출력
  WRITE: / '선택한 파일 경로:', p_file.

  " Step 1: 엑셀 데이터를 인터널테이블로 변환하여 읽기
  CALL FUNCTION 'ALSM_EXCEL_TO_INTERNAL_TABLE'
    EXPORTING
      filename    = p_file      " 사용자가 선택한 파일 경로
      i_begin_col = 1           " 시작 컬럼 (첫 번째 컬럼)
      i_begin_row = 2           " 데이터가 시작하는 행 (두 번째 행부터 데이터 시작)
      i_end_col   = 16          " 컬럼 개수 (필요에 따라 조정 가능)
      i_end_row   = 1000        " 최대 1000개 행 읽기 (필요에 따라 조정 가능)
    TABLES
      intern      = lt_excel_raw " 엑셀 데이터를 저장할 인터널테이블
    EXCEPTIONS
      OTHERS      = 1.      " 오류 발생 시 예외 처리

  IF sy-subrc <> 0.
    WRITE: '엑셀 파일 업로드 실패!'.
    EXIT.
  ENDIF.

  " Step 2: 변환된 데이터를 실제 테이블(ztable) 구조로 매핑
  CLEAR: lt_excel.
  LOOP AT lt_excel_raw INTO ls_raw.
    " 엑셀 데이터의 컬럼 번호에 따라 ZTABLE의 필드에 매핑
    CASE ls_raw-col.
      WHEN 1. ls_excel-mandt   = ls_raw-value.        " 첫 번째 컬럼 → 클라이언트 정보
      WHEN 2. ls_excel-userid  = ls_raw-value.        " 두 번째 컬럼 → 사용자 ID
      WHEN 3.
        ls_excel-passwd  = ls_raw-value.               " 세 번째 컬럼 → 패스워드
        
        " 한 행의 데이터 입력이 완료되었으므로 인터널 테이블에 추가
        APPEND ls_excel TO lt_excel.
        CLEAR: ls_excel.  " 다음 데이터를 위해 구조 초기화

    ENDCASE.


  ENDLOOP.


  " Step 3: 변환된 데이터 출력 (테스트용, 실제 프로그램에서는 필요 시 주석 처리)
  LOOP AT lt_excel INTO ls_excel.
    WRITE: / ls_excel.
  ENDLOOP.